Uitwisselprofiel ActiZ Belangenbehartiging

Over Uitwisselprofiel ActiZ Belangenbehartiging

Publicatiedatum:
22-01-2026
Inwerkingtreding:
01-02-2026
Bekijk bron...

1.7. Wat is het aantal cliënten met een Wlz-indicatie per sector?

Concepten

Relaties

Eigenschappen

Instanties

SPARQL query

Code gekopieerd
...
Kopieer naar klembord
1# Indicator: ActiZ 1.7
2# Parameters: ?jaar ?kwartaal
3# Ontologie: versie 3.0 of nieuwer
4
5PREFIX onz-g:   <http://purl.org/ozo/onz-g#>
6PREFIX onz-org: <http://purl.org/ozo/onz-org#>
7PREFIX onz-zorg:<http://purl.org/ozo/onz-zorg#>
8PREFIX xsd:     <http://www.w3.org/2001/XMLSchema#>
9
10
11SELECT
12    (?vestiging AS ?Indeling)
13    (IF(?vestiging = "Totaal organisatie", "", SAMPLE(?zk_regio_code)) AS ?Zorgkantoorregio_code)
14    (COUNT(DISTINCT IF(?sector = onz-zorg:VV, ?client, ?unbound)) AS ?VV)
15    (COUNT(DISTINCT IF(?sector = onz-zorg:LG, ?client, ?unbound)) AS ?LG)
16    (COUNT(DISTINCT IF(?sector = onz-zorg:LVG, ?client, ?unbound)) AS ?LVG)
17    (COUNT(DISTINCT IF(?sector = onz-zorg:VG, ?client, ?unbound)) AS ?VG)
18    (COUNT(DISTINCT IF(?sector = onz-zorg:ZGAUD, ?client, ?unbound)) AS ?ZGAUD)
19    (COUNT(DISTINCT IF(?sector = onz-zorg:ZGVIS, ?client, ?unbound)) AS ?ZGVIS)
20    (COUNT(DISTINCT IF(?sector = onz-zorg:GGZ-B, ?client, ?unbound)) AS ?GGZ_B)
21    (COUNT(DISTINCT IF(?sector = onz-zorg:GGZ-W, ?client, ?unbound)) AS ?GGZ_W)
22{
23#     BIND(2024 AS ?jaar)
24#     BIND("Q1" AS ?kwartaal)
25    
26    BIND(
27        IF(?kwartaal = 'Q1', xsd:date(CONCAT(STR(?jaar), '-01-01')),
28            IF(?kwartaal = 'Q2', xsd:date(CONCAT(STR(?jaar), '-04-01')),
29                IF(?kwartaal = 'Q3', xsd:date(CONCAT(STR(?jaar), '-07-01')),
30                    IF(?kwartaal = 'Q4', xsd:date(CONCAT(STR(?jaar), '-10-01')),
31                        ''))))
32        AS ?p_start
33    )
34    BIND(?p_start + "P3M"^^xsd:duration + "-P1D"^^xsd:duration AS ?p_eind)
35    
36    ?sector
37        a onz-zorg:LangdurigeZorgSector .
38    ?client
39        a onz-g:Human .
40    
41    ?indicatie
42        a onz-zorg:WlzIndicatie ;
43        onz-g:isAbout ?client ;
44        onz-g:hasPart/onz-g:isAbout ?sector ;
45        onz-g:startDatum ?start_indicatie .
46        OPTIONAL {?indicatie onz-g:eindDatum ?eind_indicatie}
47        FILTER(?start_indicatie <= ?p_eind && ( !BOUND(?eind_indicatie) || ?eind_indicatie >= ?p_start ))
48    
49    # Koppel een zorgproces aan de Wlz indicaties en locaties
50    ?zorgproces a onz-g:CureAndCareProcess ;
51                onz-g:definedBy ?indicatie ;
52                onz-g:hasPerdurantLocation/onz-g:partOf* ?locatie ;
53                onz-g:startDatum ?start_zorgproces .
54    OPTIONAL { ?zorgproces onz-g:eindDatum ?eind_zorgproces }
55    FILTER(?start_zorgproces <= ?p_eind && ( !BOUND(?eind_zorgproces) || ?eind_zorgproces >= ?p_start ))
56    
57    # Locatie en vestiging structuur
58  {
59    ?locatie onz-g:partOf* ?vestiging_uri .
60    ?vestiging_uri a onz-org:Vestiging ;
61      onz-g:identifiedBy ?vest_nr ;
62      onz-g:hasLocalizableArea/onz-g:identifiedBy/onz-g:hasPart/onz-g:hasPart ?postcode_6 .
63    ?vest_nr a onz-org:Vestigingsnummer ;
64      onz-g:hasDataValue ?vestiging .
65
66    BIND(IRI(SUBSTR(STR(?postcode_6), 1, STRLEN(STR(?postcode_6)) - 2)) AS ?postcode)
67    ?pc_gebied onz-g:identifiedBy ?postcode ;
68      onz-g:partOf+ ?zk_regio .
69    ?zk_regio a onz-org:ZorgkantoorRegio .
70  } UNION {
71    ?locatie onz-g:partOf* ?vestiging_uri .
72    ?vestiging_uri onz-org:vestigingVan ?organisatie_uri .
73    BIND("Totaal organisatie" AS ?vestiging)
74  }
75
76    BIND(IF(BOUND(?zk_regio), STRAFTER(STR(?zk_regio), "/onz-org/"), ?unbound) AS ?zk_regio_code)
77    
78    
79
80}
81GROUP BY ?vestiging ?zk_regio_code
82ORDER BY ?vestiging ?zk_regio_code
83
Terug naar: 1.6. Wat is het aantal cliënten per financieringsstroom?